Stataコマンド早見表

• 作業フォルダに格納されている複数のCSVファイルを読み込んでdtaファイルとして保存し、1つのdtaファイルに結合します。
• 複数のCSVファイルには同一の列が格納されており、縦方向に結合して1つのファイルにまとめます。
• インポート、マクロ変数、繰返し処理などのコマンドを使用します。

* 作業フォルダを指定します。
cd "ここにCSVファイルが格納されているパスを記述します。"

* マクロ変数にファイル名（CSVのみ）を格納します。
local filelist : dir . file "*.csv", respectcase

* 繰返し処理でファイルごとに処理を行います。
foreach file of local filelist {

	* CSVファイルをインポートします。
	import delimited "`file'", clear

	* マクロ変数にファイル名を格納します。
	local fname = subinstr("`file'",".csv","",.)

	* dtaファイルとして保存します。
	save "`fname'.dta"
	
	* データセットをクリアします。
	clear
}

* マクロ変数にファイル名（dtaのみ）を格納します。
local filelist : dir . file "*.dta", respectcase

* dtaファイルを縦方向に結合します。
append using `filelist'

* dtaファイルを保存します。
save "append_dataset.dta"


コピー

• 2つの回帰モデルを作成し、その結果を比較する表を生成して、Excelファイルに出力します。
• Stataでは回帰モデルの結果を参照するには保存する操作が必要であり、estimates storeコマンドにより保存できます。
• こちらの例では2つの回帰モデルですが、3つ以上のモデルも同様の操作で表を作成、出力できます。

* サンプルデータを読込みます。
webuse lbw

* 回帰モデル（1つ目）を作成します。
regress bwt age lwt

* 作成した回帰モデルを保存します。
estimates store model1

* 回帰モデル（2つ目）を作成します。
regress bwt age lwt i.smoke i.ptl

* 作成した回帰モデルを保存します。
estimates store model2

* 2つの回帰モデルの表を作成します。
etable, estimates(model1 model2) mstat(N) mstat(r2) column(index)

* 表をExcelファイルとしてエクスポートします。
collect export tworegs.xlsx


コピー

• ヘッダー情報が複数行のデータをインポートするコマンド例です。
• DPCデータ（Excelファイル）は厚生労働省のホームページよりダウンロードできます。
• すべての列を文字列型で読み込んだあと、変数名と変数ラベルを編集し、特定の変数を数値型に変換します。

* はじめに、厚生労働省のホームページより
* （８）疾患別手術別集計_MDC01（Excel：2,991KB）
* をダウンロードして作業フォルダに格納します。
* 作業フォルダは、cdコマンドを実行すると表示されます。

* Excelファイルを読込みます。
import excel 001076045.xlsx, allstring

* 告示番号、通番、施設名の変数名と変数ラベルを設定します。
rename A kokuji
rename B tsuban
rename C shisetsu
label variable kokuji "告示番号"
label variable tsuban "通番"
label variable shisetsu "施設名"

* 変数名の一覧を取得します。
ds

* 変数名と変数ラベルを編集します。
local cnamelist = "`r(varlist)'"
local n1 = ""
local n2 = ""
local n3 = ""
local n4 = ""
foreach cname of local cnamelist {
	* 1,2行目の情報を取得します。
	if `cname'[1] != "" {
		local n1 = `cname'[1]
		local n2 = `cname'[2]
	}
	* 3行目の情報を取得します。
	if `cname'[3] == "件数" {
		local n3 = "cnt"
	}
	else if `cname'[3] == "在院日数" {
	    local n3 = "day"
	}
	* 4行目の情報を取得します。
	* 4行目の文字列が3文字以上の場合は変数名の末尾を"xx"とします。
	if ustrlen(`cname'[4]) > 2 {
		local n4 = "xx"
	}
	else {
		local n4 = `cname'[4]
	}
	* 変数名と変数ラベルを設定します。
	* 変数名の先頭に数値を使用できないため、先頭に"a"を付与します。
	if "`n1'" != "" {
	    local labvar = `cname'[4]
	    label variable `cname' "`n1'_`n2'_`n3'_`labvar'"
		rename `cname' a`n1'_`n3'_`n4'
	}
}

* 不要な行を削除します。
drop if _n <= 4

* 施設名以外の変数を数値型へ変換します。
destring kokuji tsuban a*, replace force


コピー

• levelsofコマンドでカテゴリーを取得し、繰返し処理に使用します。
• 変数yhat_by_catに予測値が格納されますが、変数rep78の値ごとに回帰式は異なります。
• predictコマンドでresidualsオプションを指定して残差を求めることも可能です。

* サンプルデータを読込みます。
webuse auto

* 予測値を格納するための変数を生成します。
gen double yhat_by_cat = .

* カテゴリーを取得します。
levelsof rep78

* カテゴリーごとに処理を繰り返します。
foreach i in `r(levels)' {
	* 回帰分析を実行します。
	regress price weight if rep78 == `i'
	
	* 予測値を一時変数に格納します。
	predict tmp if rep78 == `i'
	
	* 予測値を格納します。
	replace yhat_by_cat = tmp if rep78 == `i'
	
	* 一時変数を削除します。
	drop tmp
}


コピー