Sample Scripts from GB Books
GB003:  2次元における電導

これまでは均一な材質からなるオブジェクトのみを扱ってきましたが、FlexPDEでは材質が連続的に変化する場合や不連続に変化する場合も容易に扱えます。ここでは右図に示すように上半分は銅、下半分は鉄からなる金属プレートを考えることにします。ハッチングを施した境界は絶縁されているとし、左上隅に U = 1 の電位をかけ、右下隅の電位は U = 0 に保つものとします。このときの電導のパターンを調べてみましょう。
台形プレートのときの econduction01b.pde をベースにスクリプトを作成します。

  TITLE
    'Conduction in a Rectangular Plate(Cu/Fe)'  { econduction01f.pde }

  SELECT
    Errlim = 3e-4

  VARIABLES
    U                     { Electric potential }

DEFINITIONSセクションで規定するパラメータ cond の値はデフォルト値の性格を持ちます。以下で 'iron' リージョンを定義する際、リージョン固有の cond の値を設定している点に注意してください。
  DEFINITIONS
    Lx = 1  Ly = 1.0
    cond = 5.99e7         { Conductivity of Cu }
    Ex = -dx(U)  Ey = -dy(U)  E = -grad(U)  Em = magnitude(E)
    Jx = cond*Ex  Jy = cond*Ey  J = cond*E  Jm = magnitude(J) 
                          { Electrical current density }
    J_angle = sign(Jy)*arccos(Jx/Jm)/PI*180

  EQUATIONS
    div(J)=0              { 2nd order PDE in U }

BOUNDARIESセクションでは最初にドメイン全体を Region1 として定義、次に Region 'iron' という形で鉄製のリージョンを定義します。
  BOUNDARIES
    Region 1              { Entire domain }
      Start 'boundary' (0, -Ly)
        Value(U) = 0    Line to (Lx, -Ly) to (Lx, 0)
        Natural(U) = 0  Line to (Lx, Ly) to (0, Ly)  { Insulated }
        Value(U) = 1.0  Line to (-Lx, Ly) to (-Lx, 0)
        Natural(U) = 0  Line to (-Lx, -Ly) to Close  { Insulated }

    Region 'iron' cond = 1.03e7  { Iron region }
      Start (-Lx, -Ly) 
        Line to (Lx, -Ly) to (Lx, 0) to (-Lx, 0) to Close

Ex, Ey, Jx, Jy の等高線プロットの指定において zoom という修飾子が用いられています。これはドメインの一部分のみを拡大表示するためです。
  PLOTS
    Grid(x, y)
    Contour(U)    Elevation(U) on 'boundary'
    Elevation(normal(J)) on 'boundary'
    Vector(J) norm
    Contour(J_angle) painted
    Contour(Ex) painted zoom(-Lx/2, -Ly/2, Lx, Ly)
    Contour(Ey) painted zoom(-Lx/2, -Ly/2, Lx, Ly)
    Contour(Jx) painted zoom(-Lx/2, -Ly/2, Lx, Ly)
    Contour(Jy) painted zoom(-Lx/2, -Ly/2, Lx, Ly)

  END

(1) Grid(x, y)
Grid#4 という表示に示されているように、所定の精度を得るために3回のメッシュ再構成が行われています。

(2) Contour(U)
解析対象領域（ドメイン）上での関数 U(x, y) の等高線図、すなわち等電位線は次のようになります。 銅と鉄との境界をまたいで等電位線は連続ですが、向きは大きく変化しています。

(3) Elevation(U) on 'boundary'
関数 U の値を境界線上でプロットしたものです。左上隅で U = 1、右下隅で U = 0 であることが確認できます。

(4) Elevation(normal(J)) on 'boundary'
電流密度ベクトル J の法線成分の値を境界上でプロットしたものです。絶縁境界部分で値が0となっていることが確認できます。

(5) Vector(J) norm
電流密度ベクトル J のベクトル場の様子をプロットしたものです。U の等高線とは直交する流れとなっています。また材質境界では回折が起こっています。

(6) Contour(J_angle) painted
電流密度ベクトル J の角度について等高線図を描いたものです。

(7) Contour(Ex) painted zoom(-Lx/2, -Ly/2, Lx, Ly)
電場ベクトル E のx成分の値に関する塗りつぶしを施した等高線図です。表示されているのは座標点 (-Lx/2, -Ly/2) より右にLx, 上にLyの範囲である点に注意してください。伝導率の異なる材質境界をはさんで Ex の値が連続的に変化していることが確認できますが、これは理論からの要請 ^*1 に符合するものでもあります。

(8) Contour(Ey) painted zoom(-Lx/2, -Ly/2, Lx, Ly)
電場ベクトル E のy成分の値に関する塗りつぶしを施した等高線図です。ドメインの中央部を拡大表示したものですが、Ey の値は材質境界の両側で不連続に変化している点に注意してください（Jy の方は連続的に変化します）。

(9) Contour(Jx) painted zoom(-Lx/2, -Ly/2, Lx, Ly)
電流密度ベクトル J のx成分の値に関する塗りつぶしを施した等高線図です。Ex の場合と異なり、Jx の値は材質境界をはさんで不連続となります。

(10) Contour(Jy) painted zoom(-Lx/2, -Ly/2, Lx, Ly)
電流密度ベクトル J のｙ成分の値に関する塗りつぶしを施した等高線図です。Ey の場合と異なり、Jy の値は材質境界をはさんで連続的に変化します。

*1     Cheng, D. K. Field and Wave Electromagnetics, 2nd edn, Addison-Wesley, 1989