Sample Scripts from GB Books
GB002:  2次元静電場

今度は E₀ という平行な静電場の中に断面が円形の金属棒を配置したときに、その周辺で電場がどう変化するかを調べてみます。解析対象のドメインとしては最初の例と同じものを使用しますが、境界条件の設定が全く異なったものとなります。すなわちドメイン境界上で U の外向き法線微分の値を指定します。すなわち上辺と下辺上では

ですが、右辺上では

を、左辺上では

を指定することになります。なお、金属棒表面上での電位は0とします。

estatic01a.pde をベースに次のようなスクリプトを用意します。
  TITLE
    'Metal Rod across a Parallel Field'    { estatic01c.pde }

  SELECT
    Errlim = 1e-4

  VARIABLES
    U                           { Electric potential }

  DEFINITIONS
    L = 1    r0 = 0.3    E0x = 1e3
    Ex = -dx(U)    Ey = -dy(U)
    E = -grad(U)    Em = magnitude(E)

  EQUATIONS
    div(grad(U)) = 0

  BOUNDARIES
    Region 1
      Start 'outer' (-L, -L)
        Natural(U) = 0     Line to (L, -L)
        Natural(U) = -E0x  Line to (L, L)
        Natural(U) = 0     Line to (-L, L)
        Natural(U) = E0x   Line to Close
      Start 'rod' (r0, 0)
        Value(U) = 0       Arc(Center = 0,0) Angle = 360

  PLOTS
    Grid(x, y)
    Contour(U)    Surface(U)
    Elevation(U) on 'outer'    Elevation(U) on 'rod'
    Contour(Em)    Vector(E)
    Elevation(Ex) on 'outer'    Elevation(Em) on 'rod'

  END

(1) Grid(x, y)
FlexPDEによって自動生成されたメッシュの構成を次に示します。

(2) Contour(U)
解析対象領域（ドメイン）上での関数 U(x, y) の等高線図、すなわち等電位線は次のようになります。

(3) Surface(U)
関数 U(x, y) の曲面の形状をプロットしたものです。

(4) Elevation(U) on 'outer'
U(x, y) の値を外側の境界'outer'上でプロットしたものです。

(5) Elevation(U) on 'rod'
U(x, y) の値を内側の境界'rod'上でプロットしたものです。一見指定値0から大きくはずれているように見えるかも知れませんが、スケールが e-12 である点にご注意ください。

(6) Contour(Em)
電場ベクトル E の絶対値（大きさ）に関する等高線図を示したものです。 金属棒の左右端で Em の値は最も大きく、上下端ではほとんど0となっている点にご注意ください。

(7) Vector(E)
電場ベクトル E のベクトル場をプロットしたものです。電場ベクトル E は静電ポテンシャル U の勾配（gradient）として導かれるわけですが、その絶対値 Em が'rod'の上下端で0となること、及び左右端で最大となることは(3)の曲面図の形状、勾配から読み取れます。

(8) Elevation(Ex) on 'outer'
Ex の値を外側の境界上でプロットしたものです。左右の境界上で指定値どおりであることを確認ください。なお(4)のelevationプロットに見られるように、U の値は左右の境界上で一定ではありません。

(9) Elevation(Em) on 'rod'
電場ベクトル E の大きさを内側の境界である'rod'上でプロットしたものです。